精品主图公式下载 大智慧精品

指标公式详细说明

精品主图

{精品主图}
n:=10;
r5:ma(close,5),precis2,color0099cc,linethick2;
r10:ma(close,10),precis2,color009900,linethick2;
r20:=ma(close,20);
r30:ma(close,30),colorff9933;
r60:ma(close,60),precis2,linethick1,colorred;
强弱:ema(cost(60),10),precis2,colora9a9a9,dotline,linethick1;
lhnh:=barslast(dispstatus=1)+1;
nnl:=dispstatus=2;
p:=backset(nnl,hhvbars(h,lhnh)+1);
b:=p>ref(p,1);
p2:=backset(nnl,llvbars(l,lhnh)+1);
b2:=p2>ref(p2,1);
高:ref(h,barslast(b)),precis2,colorred,linethick1;
drawtext(nnl,高,'高： ￥'+高),align2,colorgreen;
低:ref(l,barslast(b2)),precis2,colorgreen,linethick1;
drawtext(nnl,低*1.009,'低： ￥'+低),align2,colorgreen;
f6:((高-低)*0.236)+低,precis0,colora9a9a9;
drawtext(barslast(b)>barslast(b2) and nnl,f6,'0.236： ￥'+f6),align2,colorgreen;
f2:((高-低)*0.382)+低,precis0,colora9a9a9;
drawtext(barslast(b)>barslast(b2) and nnl,f2,'0.382： ￥'+f2),align2,colorgreen;
f3:((高-低)*0.5)+低,precis0,color5f9ea0;
drawtext(nnl,f3,'0.5：￥'+f3),align2,colorgreen;
f4:((高-低)*0.618)+低,precis0,colora9a9a9;
drawtext(barslast(b)>barslast(b2)and nnl,f4,'0.618： ￥'+f4),align2,colorgreen;
f5:((高-低)*0.764)+低,precis0,colora9a9a9;
drawtext(barslast(b)>barslast(b2) and nnl,f5,'0.764： ￥'+f5),align2,colorgreen;
pday1 := barslast(cross(r5,r60));{5日均线上穿60日均线}
pday2 := barslast(cross(r10,r60));{10日均线上穿60日均线，至此形成颈部}
pday3 := barslast(high=hhv(high,pday2));{形成头部，要下跌}
pday4 := barslast(cross(r10,r5));{下跌后，5日均线和10日均线死叉}
pday5 := barslast(cross(r5,r10));{回落不久，5日均线和10日均线形成金叉，形成d部}
a1:= pday1>pday2 and pday2>pday3 and pday3>pday4 and pday4>pday5 and pday5<5;
a2:= count(cross(r10,r5),pday2)=1;
aa:=if(a1 and a2 and ma(c,5)>=ma(c,10) and ma(c,10)>ma(c,60),10,0);
bb:=filter( a1 and a2 and ma(c,5)>=ma(c,10) and ma(c,10)>ma(c,60),5);
有戏:=if(aa and bb,1,0);
drawicon(aa and bb ,low*0.99,1),align1;
a0:=amount/vol/100;
a3:=(ema(a0,3)>ema(a0,7) and ema(a0,7)>ema(a0,13) and ema(a0,13)>ema(a0,21));
drawtext(a3,ma(c,60),'*'),align1,colorred;
gj:=(c+h+l+o)/4;
明阻:=l+(gj-l)+(c-l);
明支:=l+(c-gj);
阻:ref(明阻 , 1),linethick0,precis2,colorred;
支:ref(明支 , 1),linethick0,precis2,colorff00ff;
stickline(dispstatus=2 and c>=阻,阻*1.001,阻*0.999,15,0),color0000ff;
stickline(dispstatus=2 and c<阻,阻*1.001,阻*0.999,15,0),color00ff00;
stickline(dispstatus=2 and c>=支,支*1.001,支*0.999,15,0),colorff00ff;
stickline(dispstatus=2 and c<支,支*1.001,支*0.999,15,0),colorff8800;
mtm:=c-ref(c,1);
dx:=100*ema(ema(mtm,6),6)/ema(ema(abs(mtm),6),6);
zx:=100*ema(ema(mtm,12),12)/ema(ema(abs(mtm),12),12);
cx:=100*ema(ema(mtm,26),26)/ema(ema(abs(mtm),26),26);
dxgd:=llv(dx,2)=llv(dx,5) and cross(dx,ma(dx,2));
zxgd:=llv(zx,2)=llv(zx,5) and cross(zx,ma(zx,2)) and dx>zx;
短买:=if(dxgd and between(dx,0,60) and zx>0,1,0);
中买:=if(zxgd and between(dx,0,50) and between(cx,0,50),1,0);
dtpl:=dx>zx and zx>cx and cx>0;
qsxs:=dx>ref(dx,1) and zx>ref(zx,1);
tsjc:=cross(dx,cx) and cross(zx,cx);
优选:=if(cross(dtpl,0.8) and (tsjc or count(qsxs,3)=3) and cx<40,1,0);
短卖:=if(cross(zx,dx),1,0);
中卖:=if(cross(cx,zx) and dx<zx,1,0);
买:=if(llv(dx,2)=llv(dx,7) and count(dx<0,2) and cross(dx,ma(dx,2)),1,0);
卖:=if(hhv(dx,2)=hhv(dx,7) and count(dx>50,2) and cross(ma(dx,2),dx),1,0);
drawtext(短买,low*0.99,'△'),colore91daf,align1;
drawtext(中买,low*0.99,'▲'),colore91daf,align1;
drawtext(短卖,high*1.02,'▽'),colorff0000,align1;
drawtext(中卖,high*1.02,'▼'),colorff0000,align1;
drawtext(filter(买=1,5),low-0.03,'★'),colore91adf,align1;
drawtext(filter(卖=1,5),high*1.015,'★'),colorff0000,align1;
drawicon(优选,low-0.03,7);
rsv:=(c-llv(l,9))/(hhv(h,9)-llv(l,9))*100;
k1:=sma(rsv,3,1);
d1:=sma(k1,3,1);
j1:=3*k1-2*d1;
bdgd1:=hhv(j1,2)=hhv(j1,8) and j1>80;
bddd:=llv(j1,2)=llv(j1,8);
j1向下拐头:=if(cross(ref(j1-0.01,1),j1) and ref(bdgd1,1),1,0);
drawtext(j1向下拐头 ,high*1.015,'j'),colorffffff;
j1向上拐头:=if(cross(j1,ref(j1+0.01,1)) and bddd and j1<20,1,0);
drawtext(j1向上拐头,low*0.993,'j'),color00ffff;
wr2:=100*(hhv(high,6)-close)/(hhv(high,6)-llv(low,6));
ddsj:=barslast((1-c/ref(c,1))*100>=2);
xd:=c<ref(c,1);
df:=(hhv(h,5)/c-1)*100>=5;
跌6:=count(xd,6)>=5 and xd and df and ddsj<=1;
跌9:=wr2>80;
底:=跌6 and 跌9;
typ := (high + low + close)/3;
cci:=(typ-ma(typ,14))/(0.015*avedev(typ,14));
a:=ref(c,1);
rsi:=sma(max(c-a,0),6,1)/sma(abs(c-a),6,1)*100;
a11:=(c/ma(c,5)-1)*100<-10;
a21:=(c/ma(c,13)-1)*100<-10;
a31:=(c/ma(c,34)-1)*100<-15;
a41:=rsi<18;
a51:=cci<-120;
a61:=count(abs(c/ref(c,1)-1)*100>=6,30)>=1;
底部:=a11 and a21 and a31 and a41 and a51 and a61;
drawtext(底部,low*0.99,'底'),color00ff00;
drawtext(底>0,low-0.03,'d'),colorffffff,align1;
bdgd:=c=hhv(c,n);
gdsj:=barslast(bdgd);
前高1:=if(gdsj>0,ref(c,gdsj),ref(c,gdsj));
tp1:=cross(c,ref(前高1,1));
突破1:=tp1 and count(tp1,5)=1;
stickline(突破1,(o+c)/2*1.01,(o+c)/2*1.01,15,0),color00ff00;
主筹估算:=ema(winner(c)*70,3);
散筹估算:=ema((winner((c)*1.1)-winner((c)*0.9))*70,3);
筹码锁定:=散筹估算-主筹估算 ;
动态底部:=ema(if(l<= llv(l,60),sma(abs(l-ref(l,1)),60,1)/sma(max(l-ref(l,1),0),99,1),0)*5,3);
涨:=cross(主筹估算,筹码锁定);
强:=cross(主筹估算,散筹估算);
stickline(涨,o,c,4,1),coloryellow;
stickline(涨,o,h,0,0),coloryellow;
stickline(涨,l,c,0,0),coloryellow;
stickline(强, o,c,4,1),colormagenta;
stickline(强,o,h,0,0),colormagenta;
stickline(强,l,c,0,0),colormagenta;
stickline(筹码锁定<-50,o,c,4,1),colorred;
stickline(筹码锁定<-50,o,h,0,0),colorred;
stickline(筹码锁定<-50,l,c,0,0),colorred;
买入:=strfind(extrastring('评级'),'买入',1)>0;
增持:=strfind(extrastring('评级'),'增持',1)>0;
持有:=strfind(extrastring('评级'),'持有',1)>0;
drawtextrel(400,970,'评级:'+extrastring('评级')),colora9a9a9;
{drawtextabs(5,360,'板块:'+bkname),colora9a9a9;}
流通:=finance2(37)/10000;
市盈率:=dynainfo(39);
f:=cost(5 );j:=cost(95 );
m:=cost(15 );x:=cost(85 );
f1:=(j-f)/(f+j)*100;m1:=(x-m)/(x+m)*100;
集中度90:=f1;
集中度70:=m1;
获利盘:=winner(close)*100;
套牢盘:=100*(1-winner(c));
收益:=finance2(3);
浮筹比:=(winner(c*1.1)-winner(c*0.9))/winner(hhv(h,0))*100;
drawtextabs(5,65,'浮筹比:'+浮筹比+'% '),linethick1,colora9a9a9;
drawtextabs(110,20,'流通:'+流通+' '),linethick1,colora9a9a9;
drawtextabs(5,80,'市盈率:'+市盈率+' '),linethick1,colora9a9a9;
drawtextabs(5,5,'集中度90:'+集中度90+' '),linethick1,color00ff00;
drawtextabs(5,20,'集中度70:'+集中度70+' '),linethick1,coloryellow;
drawtextabs(5,35,'获利盘:'+获利盘+'% '),linethick1,colora9a9a9;
drawtextabs(5,50,'套牢盘:'+套牢盘+'% '),linethick1,colora9a9a9;
drawtextabs(110,5,'收益:'+收益+'元 '),linethick1,colora9a9a9;

点击看大图

指标公式下载地址

上一指标公式：洗盘信号公式下载 大智慧洗盘

下一指标公式：多空列阵通达信公式下载 大智慧通达信列阵

相关大智慧公式推荐

指标公式下载注意

☉ 好公式网发布的指标公式主要用于软件技术面分析，仅供参考，勿用于实际操作，据此操作风险自负！

☉ 解压密码：www.goodgongshi.com 就是好公式网域名，希望大家看清楚，切勿输错。

☉ tnc和tni格式指标公式，仅可以用通达信软件引入使用，例如可以用通达信软件引入使用指标公式；

☉ tne格式指标公式，仅可以用通达信软件公式编辑器5.0版导入，高版本兼容低版本；

☉ fnc格式指标公式，可以用大智慧软件新一代高速行情分析系统股票软件使用，少部分可以用分析家软件引入使用；

☉ alg格式指标公式，仅仅可以用飞狐交易师软件引入使用；exp格式指标公式，仅可以用大智慧经典版软件引入使用；

☉ hxf格式指标公式，仅可以用同花顺软件引入使用。

☉ 如果您发现下载软件链接错误，请联系管理员报告错误。

☉ 好公式网欢迎各位网友帮忙宣传转发本站网址，有您的支持，我们会做得更好！

☉ 本文精品主图公式下载 大智慧精品仅供学习研究。