珍藏“自用抓牛股超好”{副图附图}指标下载 通达信附图牛股

指标公式详细说明

指标用法很简单，仔细看看附图就能明白！强势股需日，周，月周期共振。

经典的才是最好的！
淘指标淘到最后你自己就能明白！！！相信不少人都懂的......

源码：
{macd}
rsv:=(close-llv(low,9))/(hhv(high,9)-llv(low,9))*100;
k:sma(rsv,3,1),linethick2,colorwhite;
d:sma(k,3,1),linethick2,color00dddd;
j:3*k-2*d,linethick2,color800080;
dif:ema(close,12)-ema(close,26),linethick0,color0099ff;
dea :ema(dif,9),linethick0,colord89837;
macd:2*(dif-dea),colorff9999,linethick0;
ylzc:=if(close=indexc,(indexc+indexh+indexl+indexo)/4,amount/(vol+0.01)/100);
阻价:=if(close=indexc,ylzc+indexc-indexl,ylzc+(close-low));
支价:=if(close=indexc,indexl+indexc-ylzc,low+(close-ylzc));
今压:ref(阻价,1),linethick0,coloraa11bb;
今撑:ref(支价,1),linethick0,color009900;
明压:阻价,linethick0;
明撑:支价,linethick0;
rsv1:=(hhv(h,9.8)-c)/(hhv(h,9.8)-llv(l,9.8))*101;
kk:=sma(rsv1,3,1);
dd:=sma(kk,3,1);
jj:=3*kk-2*dd;
买卖:=if(jj>=100,100,if(jj<=0,0,jj));
明天买:if(买卖=100,0-10,0),color00cccc;
明天卖:if(买卖=0,90,100),color00ff00;
kx:=250;
kh:=hhv(k,kx);
dh:=hhv(d,kx);
jh:=hhv(j,kx);
kl:=llv(k,kx);
dl:=llv(d,kx);
jl:=llv(j,kx);
hkmax:=max(kh,max(dh,jh));
lkmin:=min(kl,min(dl,jl));
khlb:=(hkmax+lkmin)/2;
khlc:=hkmax-lkmin;
mhf:=hhv(dif,kx);
mhd:=hhv(dea,kx);
mhm:=hhv(macd,kx);
mlf:=llv(dif,kx);
mld:=llv(dea,kx);
mlm:=llv(macd,kx);
hmax:=max(mhf,max(mhd,mhm));
lmin:=min(mlf,min(mld,mlm));
fhlb:=(hmax-lmin)/100;
fhlc:=hmax-lmin;
sh:=(0-fhlb)*(khlc/fhlc)+khlb;
difa:=(dif-fhlb)*(khlc/fhlc)+khlb;
deaa:=(dea-fhlb)*(khlc/fhlc)+khlb;
macda:=(macd-fhlb)*(khlc/fhlc)+khlb;
cda:=macd<ref(macd,1) and macd>0;
cdb:=macd>=ref(macd,1) and macd>0;
cdc:=macd>ref(macd,1) and macd<0;
cdd:=macd<=ref(macd,1) and macd<0;
stickline(cda,sh,macda,2,0),color00aaff;{黄色段}
stickline(cdb,sh,macda,2,0),color0000aa; {红色段}
stickline(cdc,sh,macda,2,0),coloraa00bb;{向上粉红}
typ:=(high+low+close)/3;
stickline(dif>ref(dif,1),20,20,2,0),colorred;
stickline(dif<ref(dif,1),20,20,2,0),colorgreen;
stickline(k>=ref(k,1) or k>d and dif>ref(dif,1),80,80,2,1),colorred;
stickline(k<ref(k,1),80,80,2,1),colorgreen;
macd金叉:=cross(macd,dif) and macd>=(0-0.05) and macd<=0.02;
drawtext(macd金叉,macda*0.82,'▲macd金叉'),color00ffff;
xx:=ema(ma(low,3)*0.96,30);
dif金叉:=if(cross(dif,dea) and xx-ref(xx,1)>0 and macd>=ref(macd,1) and dif<=0,1,0);
drawtext(dif金叉=1,difa*1.68,'dif金叉'),colorcdffbb;
低位金叉:=cross(dif,dea) and dif<-0.1;
drawtext(低位金叉,deaa*0.99,'▲dif低位金叉'),color0099dd;
difdea:=count(cross(dif,dea),barslast(dea>=0));
二次金叉:=cross(dif,dea) and dea<0 and count(difdea=2,21)=1;
drawtext(二次金叉,deaa*0.99-8,'▲dif 二次金叉'),colorff00ff;
a1:=barslast(ref(cross(dif,dea),1));
底背离:=ref(close,a1+1)>close and dif>ref(dif,a1+1) and cross(dif,dea);
drawtext(底背离,deaa*0.99-16,'▲dif底背离'),color0099ff;
a2:=barslast(ref(cross(dea,dif),1));
顶背离:=ref(close,a2+1)<close and ref(dif,a2+1)>dif and cross(dea,dif);
drawtext(filter(顶背离,5),deaa*1.02,'▲dif顶背离'),colorddaaaa;

{周金叉,死叉}
周dif:="macd.dif#week";
周dea:="macd.dea#week";
周macd:="macd.macd#week";
dif周金叉:=cross(周dif,周dea);
drawtext(dif周金叉,deaa,'dif周金叉'),color0099ff;
drawtext(cross(周dea,周dif),deaa+4,'▲dif周死叉'),colorcdffbb;
macd周金叉:=cross(周macd,周dif) and 周macd>=(0-0.05) and 周macd<=0.02;
drawtext(macd周金叉,macda-0.03,'▲macd周金叉'),color00ffff;
{月金叉,死叉}
月dif:="macd.dif#month";
月dea:="macd.dea#month";
dif月金叉:=cross(月dif,月dea);
drawtext(dif月金叉,deaa*0.98,'★dif月金叉'),color00ffcc;
drawtext(cross(月dea,月dif),deaa*1.02,'★dif月死叉');
周k:="kdj.k#week"(9,3,3);
周d:="kdj.d#week"(9,3,3);
周j:="kdj.j#week"(9,3,3);
月k:="kdj.k#month"(9,3,3);
月d:="kdj.d#month"(9,3,3);
月j:="kdj.j#month"(9,3,3);
月金叉:=cross(月k,月d);
周金叉:=cross(周k,周d);
日金叉:=filter(cross(k,d) and k<20,4);
drawtext(月金叉,月d-2,'★'),color0022ee;
drawtext(月金叉,月d-2,'.kd月金叉'),coloryellow;
drawtext(周金叉,周d,'★'),color0022ee;
drawtext(周金叉,周d,'. kd周金叉'),colorgreen;
drawicon(日金叉,k,1);
drawtext(日金叉,d-6,'★kd低位金叉'),color00cccc;
drawtext(cross(周d,周k),周d*1.2,'★kd周死叉'),color00ddbb;
drawtext(cross(月d,月k),月d,'★kd月死叉'),colorffffff;
kdb:=barslast(ref(cross(k,d),1));
kddb:=ref(close,kdb+1)>close and ref(k,kdb+1)<k and cross(k,d);
k底背:=if(filter(kddb>0,5),1,0);
drawtext(k底背=1,d*0.98,'★kd底背离'),colordddddd;
kdd:=barslast(ref(cross(d,k),1));
k顶背:=ref(close,kdd+1)<close and ref(k,kdd+1)>k and cross(d,k);
drawtext(filter(k顶背>0,5),d+8,'★kd顶背离'),colorffaa22;
md1:=ma(close,80)-ma(close,13)/3;
md2:=ma((close-md1)/md1,3);
买点1:=cross(md2,0) and low/ref(high,1)<1.012 and j<75 and j>ref(j,1);
ma12:=ma(close,12);
佳点:=if(filter(macd>=ref(macd,5) and open<=ref(close,1) and xx-ref(xx,1)>0 and macd<=0 and ma12-ref(ma12,1)>=0,3) and j<80 and j>ref(j,1) and d>ref(d,1) and (dif>=ref(dif,1) or dea>=ref(dea,1)),1,0);
drawtext(佳点=1,macda*0.98,'★佳点'),color0099ff;
dx0:=ema(close,2)-ema(open,5);
dx1:=if(cross(dx0,macd) and low<=xx and macd<=(0-0.11) and (j<20 or k<20),1,0);
drawtext(filter(dx1,3),0,'★短10%'),color00cc00;{短线}
ma10:=ma(close,10);
ss:=ema(ma(high,3)*1.05,30);
lqs:=if(filter(0.7*(cross(dif,dea) and close<ss and xx-ref(xx,1)>0 and cross(macd,0) and macd>=0 and dif>0 and ma10-ref(ma10,1)>0 and vol>ref(vol,1))>=0.7 and (close<ss and xx-ref(xx,1)>0),5) and j<80,1,0);
drawtext(lqs=1,macda*0.98,'★量价齐上'),colorcdffdd;{量价齐上}
最佳点:=if(count(md2>ref(md2,1),3)=3 and count(md2<0,10)=10 and ref(md2,3)=llv(md2,10) and j<80 and j>ref(j,1),1,0);
drawtext(最佳点=1,j,'★最佳点'),colorff00cc;
买点2:=ref(md2,2)=llv(md2,20) and ref(md2,2)<0.071 and ref(md2,2)<ref(md2,1) and
not(ref(low,1)>ref(high,2) and low>ref(high,1)) and close>ref(close,1) and j<75 and j>ref(j,1);
drawtext(买点1 or 买点2,d-1,'买'),colorff00cc;
{预涨}
yz:=(intpart(sma(rsv,3,1))+intpart(sma(k,3,1)))/2;
预涨:=cross(yz,50) and j<95 and dif>ref(dif,1) and low<ref(close,1);
drawtext(预涨,d*0.6,'★预涨'),colora52a2a;

指标公式下载地址

上一指标公式：K线形态解盘主图指标下载 通达信态解盘源码

下一指标公式：博杀生命线指标下载 通达信杀生

相关通达信公式推荐

指标公式下载注意

☉ 好公式网发布的指标公式主要用于软件技术面分析，仅供参考，勿用于实际操作，据此操作风险自负！

☉ 解压密码：www.goodgongshi.com 就是好公式网域名，希望大家看清楚，切勿输错。

☉ tnc和tni格式指标公式，仅可以用通达信软件引入使用，例如可以用通达信软件引入使用指标公式；

☉ tne格式指标公式，仅可以用通达信软件公式编辑器5.0版导入，高版本兼容低版本；

☉ fnc格式指标公式，可以用大智慧软件新一代高速行情分析系统股票软件使用，少部分可以用分析家软件引入使用；

☉ alg格式指标公式，仅仅可以用飞狐交易师软件引入使用；exp格式指标公式，仅可以用大智慧经典版软件引入使用；

☉ hxf格式指标公式，仅可以用同花顺软件引入使用。

☉ 如果您发现下载软件链接错误，请联系管理员报告错误。

☉ 好公式网欢迎各位网友帮忙宣传转发本站网址，有您的支持，我们会做得更好！

☉ 本文珍藏“自用抓牛股超好”{副图附图}指标下载 通达信附图牛股仅供学习研究。