两均对垒指标公式详解 同花顺对垒

指标公式详细说明

1、该指标仅在日线系统中使用；

2、买入的参数都设置为低点，卖出的参数都都设置为高点，所以一旦提示出现不用等更低价也不用等更高价。

3、出现的提示都是有一定概率的信号，不能指望100%准确。

4、出现“买”就逢低买入，出现“调”注意洗盘；

5、出现“腰”是阶段见顶，出现“顶”说明基本上见顶，需要卖出；

6、出现“多”说明近期股票转强，出现“空”说明股票变弱；

7、出现“红色向上箭头”说明可能底到，待出现“买”的信号买入，出现“绿色向下箭头”注意或许是快要阶段见顶或见顶，待出现“调”或“腰”或“顶”时卖出；

8、出现“短”一定概率可抢反弹，但要注意风险；出现“弹”时抢反弹成功率较高，且反弹幅度较大；

10、出现“中期有戏”说明主力建仓完毕，中期拉升可期，等待回调可入；出现“短期有戏”说明短期上涨概率较大，可等买入信号出现后进；

11、出现“明天会涨”尾盘买入次日卖出成功概率很高；

12、出现“止损”及时认错止损，不要死撑；出现“全抛”说明该股已经变坏，抛股回避为好。

//均线系统//

stickline(c>=o,h,l,1,1),colorred;

stickline(c>=o,c,o,8,1),colorred;

stickline(c<o,h,l,1,0),colorgreen;

stickline(c<o,c,o,8,0),colorgreen;

短期均线:ma(close,5)/2+ma(close,10)/2,colorred,linethick1;

长期均线:ma(close,20)/5+ma(close,30)/5+ma(close,60)/5+ma(close,125)/5+ma(close,250)/5,coloryellow,linethick1;

中期均线:长期均线*5/7+短期均线*2/7,colormagenta,linethick2;

短中平均:短期均线/2+中期均线/2,colorred,linethick1;

中期均下:中期均线*0.875,colorgreen,linethick1;

中期均上:=中期均线*1.125,colorgreen,linethick1;

长期均上:长期均线*1.25,coloryellow,linethick1;

长期均半:=长期均线*1.5,coloryellow,linethick1;

均线金叉:=cross(短期均线,长期均线);

均线死叉:=cross(长期均线,短期均线);

vertline(均线金叉,0),colorred,linethick2;

vertline(均线死叉,0),colorgreen,linethick2;

中期均多:=ref(中期均线,1)<ref(中期均线,2) and 中期均线>ref(中期均线,1);

vertline(中期均多,2),colorred,linethick1;

//成交量和股价关系////www.goodgongshi.com

个股涨跌:=(close-ref(close,1))/ref(close,1);

大盘涨跌:=(indexc-ref(indexc,1))/ref(indexc,1);

五日成交量均线:=ma(vol,5);

二十日成交量均线:=ma(vol,20);

成交量上限:=五日成交量均线*1.33;

成交量下限:=五日成交量均线*0.75;

成交量卖点一:=ref(vol,1)>ref(成交量上限,1) and vol<ref(vol,1) and vol>成交量下限 and ref(个股涨跌,1)>0 and 个股涨跌<0.096 and (个股涨跌>0.01 or 个股涨跌<0);

成交量卖点二:=ref(个股涨跌,1)>0.096 and ((个股涨跌<0.096 and vol<ref(vol,1) and vol>五日成交量均线) or 个股涨跌<0);

成交量卖点三:=ref(vol,1)>ref(成交量上限,1) and vol>ref(vol,1) and ref(个股涨跌,1)>0 and 个股涨跌<0;

成交量卖点四:=个股涨跌<0.096 and ref(个股涨跌,1)>0 and vol=hhv(vol,10);

成交量卖点:=成交量卖点一 or 成交量卖点二 or 成交量卖点三;

drawtext(成交量卖点,high*1.0,'←调'),colorliblue;

drawtext(成交量卖点四,high*1.0,'←调'),colorgray;

底部一:=llv((low+close+high+open)/4,60);

顶部区域:=close>底部一*1.875 and close<底部一*2.625;

半腰区域:=close>底部一*1.375 and close<底部一*1.625;

顶部卖出:=顶部区域 and (成交量卖点 or 成交量卖点四);

drawtext(顶部卖出,high*1.005,'←顶'),colorgreen;

半腰卖出:=半腰区域 and (成交量卖点 or 成交量卖点四);

drawtext(半腰卖出,high*1.02,'←y'),colorgreen;

//多空预测//

n:=5;

m:=20;

做多能量线:=sma((close-llv(low,n))/(hhv(high,n)-llv(low,n)),5,1)-0,colorred,linethick1;

做空能量线:=sma((hhv(high,m)-close)/(hhv(high,m)-llv(low,m)),2,1),colorgreen,linethick1;

周均线:=ma(close,5);

月均线:=ma(close,20);

季均线:=ma(close,60);

年均线:=ma(close,250);

月季平均:=ma(close,20)/2+ma(close,60)/2;

做多金叉:=cross(做多能量线,做空能量线) and close>季均线;

做空死叉:=cross(做空能量线,做多能量线) and close>季均线;

//drawtext(做多金叉,中期均下*0.95,'←多'),colorred;//

//drawtext(做空死叉,中期均上*1.05,'←空'),colorgreen;//

//成交测势//

成交金叉:=cross(五日成交量均线,二十日成交量均线) and 周均线>月均线 and close/open>1 and 中期均线>长期均线;

drawtext(成交金叉,high*1.025,'←爆'),coloryellow;

成交死叉:=cross(二十日成交量均线,五日成交量均线) and 中期均线>长期均线;

drawtext(成交死叉,high*1.05,'←抛'),colorgreen;

//个股买卖//

多空买点:=中期均线>长期均线 and low<=短中平均*1.01 and 五日成交量均线<二十日成交量均线*0.75 and 月均线>季均线 and close>季均线*1.02;

drawtext(多空买点,短中平均*0.98,'←买'),coloryellow;

攻击买点:=中期均线>长期均线 and (low<=中期均线*1.01 or low<=短中平均*1.01) and 五日成交量均线>二十日成交量均线;

drawtext(攻击买点,短中平均*0.95,'←买'),colormagenta;

转空止损:=中期均线>长期均线 and 做多能量线<做空能量线 and ref(close,1)>ref(月季平均,1) and close<月季平均;

drawtext(转空止损,low*0.83,'←止损'),colorgreen;

反弹买点1:=中期均线<长期均线 and 短中平均>中期均下 and ((ref(close,1)<ref(中期均下,1) and close>中期均下) or (low<中期均下 and close>中期均下));

drawtext(反弹买点1,low*0.95,'←短'),coloryellow;

反弹买点2:=中期均线<长期均线 and (ref(close,1)<ref(中期均线*0.75,1) and close>中期均线*0.75) or (low<中期均线*0.75 and close>中期均线*0.75);

drawtext(反弹买点2,low*0.95,'←弹'),colormagenta;

drawtext(均线死叉,high*1.1,'←清仓'),colorgreen;

//主力建仓//

换手率:=vol/capital*100;

季均换手率:=ma(换手率,60);

吸中筹:=intpart(200/季均换手率);

季均线波动率:=hhv(季均线,吸中筹)/llv(季均线,吸中筹);

水平建仓:=季均线波动率<1.0625 and 吸中筹;

季年线金叉:=cross(季均线,年均线);

中线有戏:=count(水平建仓,30)>=1 and 季年线金叉;

//drawtext(中线有戏,low*0.83,'★中线有戏'),colorwhite;//

//头肩测底//

日价平均:=(high+low+close+open)/4;

月均换手率:=ma(换手率,20);

吸短筹:=intpart(100/月均换手率);

日价波动率:=hhv(日价平均,吸短筹)/llv(日价平均,吸短筹);

打压建仓:=日价波动率<1.125 and 吸短筹;

季价低点:=llv(日价平均,60);

月价低点:=llv(日价平均,20);

月季线金叉:=cross(月均线,季均线);

短线有戏:=中期均线>长期均线 and 月价低点>季价低点 and 月季线金叉 and count(打压建仓,10)>=1 ;

drawtext(短线有戏,low*0.89,'★短线有戏'),colorwhite;

//明天会涨//

当天上涨:=sum(if( close>ref(close,1),vol*c,0),0);

当天下跌:=sum(if( close<ref(close,1),vol*c,0),0);

当天平盘:=sum(if( close=ref(close,1),vol*c,0),0);

流转金额:=dvol*dclose/100;

流转金额差:=流转金额-ref(流转金额,1);

净流入金额:=(当天上涨-当天下跌-0.5*当天平盘);

净流入均额:=ma(净流入金额,1);

净流入涨:=净流入均额/ref(净流入均额,1)>1;

净流入始涨:=ref(净流入涨,1)<1 and 净流入涨;

密码:=(ema(ma(流转金额,2),2))/100000;

二日比:=密码/ref(密码,1);

选股:=净流入始涨 and 密码>ref(密码,1) and 二日比>1;

日均价线:=amount/v/100;

三日均价线:=ema(日均价线,3);

突破:=中期均线>长期均线 and c>三日均价线 and 三日均价线<ref(三日均价线,1) and ref(三日均价线,1)<ref(三日均价线,2) and ref(三日均价线,2)<ref(三日均价线,3) and 选股;

drawtext(突破,low*0.86,'←明天会涨'),colorligray;

//顶底波段//

买入:=zig(3,10)>ref(zig(3,10),1) and ref(zig(3,10),1)<ref(zig(3,10),2);

卖出:=zig(3,10)<ref(zig(3,10),1) and ref(zig(3,10),1)>ref(zig(3,10),2);

drawicon(买入,low*0.95,1);

drawicon(卖出,high*1.00,2);

指标公式下载地址

好公式网提供全网最全的指标公式软件，感谢您的支持！鼠标双击图片可看大图！
下载请点击右侧“立即下载”，如只有源码，请点击本页面右侧的导入方法按图导入！
本站指标基于网友分享，仅供研究自学，勿作他用，本站对下载使用不承担任何责任！

上一指标公式：三品逃顶指标公式详解 同花顺三品

下一指标公式：一品波段指标公式详解 同花顺波段

相关同花顺公式推荐

指标公式下载注意

☉ 好公式网发布的指标公式主要用于软件技术面分析，仅供参考，勿用于实际操作，据此操作风险自负！

☉ 解压密码：www.goodgongshi.com 就是好公式网域名，希望大家看清楚，切勿输错。

☉ tnc和tni格式指标公式，仅可以用通达信软件引入使用，例如可以用通达信软件引入使用指标公式；

☉ tne格式指标公式，仅可以用通达信软件公式编辑器5.0版导入，高版本兼容低版本；

☉ fnc格式指标公式，可以用大智慧软件新一代高速行情分析系统股票软件使用，少部分可以用分析家软件引入使用；

☉ alg格式指标公式，仅仅可以用飞狐交易师软件引入使用；exp格式指标公式，仅可以用大智慧经典版软件引入使用；

☉ hxf格式指标公式，仅可以用同花顺软件引入使用。

☉ 如果您发现下载软件链接错误，请联系管理员报告错误。

☉ 好公式网欢迎各位网友帮忙宣传转发本站网址，有您的支持，我们会做得更好！

☉ 本文两均对垒指标公式详解 同花顺对垒仅供学习研究。